One Hat Cyber Team

Your IP: 216.73.216.19
Server IP: 41.128.143.86
Server: Linux host.raqmix.cloud 6.8.0-1025-azure #30~22.04.1-Ubuntu SMP Wed Mar 12 15:28:20 UTC 2025 x86_64
Server Software: Apache
PHP Version: 8.3.23
Buat File | Buat Folder

Dir : ~/usr/lib/x86_64-linux-gnu/qt5/mkspecs/features/

View File Name : link_ltcg.prf

gcc {
    # on Windows, MinGW's support for -flto=N is broken
    intel_icc {
        QMAKE_LFLAGS_LTCG ~= s/-ipo/-ipo=$$QMAKE_HOST.cpu_count/
    } else: !clang:!equals(QMAKE_HOST.os, Windows):greaterThan(QMAKE_HOST.cpu_count, 1) {
        # Override LTO number of jobs
        QMAKE_LFLAGS_LTCG ~= s/^-flto$/-flto=$$QMAKE_HOST.cpu_count/
    }

    # When doing link-time code generation, we need to pass the compiler
    # flags during linking the stage too. This file is processed after
    # default_post.prf, so the QMAKE_CXXFLAGS already contains
    # QMAKE_CXXFLAGS_DEBUG or _RELEASE.
    use_c_linker {
        # use_c_linker.prf is in effect, use the C flags
        QMAKE_LFLAGS_LTCG += $$QMAKE_CFLAGS $$QMAKE_CFLAGS_LTCG
        QMAKE_LFLAGS_APP += $$QMAKE_CFLAGS_APP
        QMAKE_LFLAGS_SHLIB += $$QMAKE_CFLAGS_SHLIB
        QMAKE_LFLAGS_PLUGIN += $$QMAKE_CFLAGS_SHLIB
    } else {
        QMAKE_LFLAGS_LTCG = $$QMAKE_CXXFLAGS $$QMAKE_LFLAGS_LTCG
        QMAKE_LFLAGS_APP += $$QMAKE_CXXFLAGS_APP
        QMAKE_LFLAGS_SHLIB += $$QMAKE_CXXFLAGS_SHLIB
        QMAKE_LFLAGS_PLUGIN += $$QMAKE_CFLAGS_SHLIB
    }
}