One Hat Cyber Team

Your IP: 216.73.216.78
Server IP: 41.128.143.86
Server: Linux host.raqmix.cloud 6.8.0-1025-azure #30~22.04.1-Ubuntu SMP Wed Mar 12 15:28:20 UTC 2025 x86_64
Server Software: Apache
PHP Version: 8.3.23
Buat File | Buat Folder

Dir : ~/lib/x86_64-linux-gnu/qt5/mkspecs/features/win32/

View File Name : opengl.prf

QT_FOR_CONFIG += gui

defineTest(prependOpenGlLib) {
    path = $$QT.core.libs/$$QMAKE_PREFIX_STATICLIB$$1
    ext = .$$QMAKE_EXTENSION_STATICLIB
    !mingw|qtConfig(debug_and_release): debug_suffix = "d"
    QMAKE_LIBS_OPENGL_ES2 = $${path}$${ext} $$QMAKE_LIBS_OPENGL_ES2
    QMAKE_LIBS_OPENGL_ES2_DEBUG = $${path}$${debug_suffix}$${ext} $$QMAKE_LIBS_OPENGL_ES2_DEBUG
    export(QMAKE_LIBS_OPENGL_ES2)
    export(QMAKE_LIBS_OPENGL_ES2_DEBUG)
}

qtConfig(opengles2) {
    # Depending on the configuration we use libQtANGLE or libEGL and libGLESv2
    qtConfig(combined-angle-lib) {
        prependOpenGlLib($$LIBQTANGLE_NAME)
    } else {
        prependOpenGlLib($$LIBGLESV2_NAME)
        prependOpenGlLib($$LIBEGL_NAME)
    }
#   For Desktop, use the ANGLE library location passed on from configure.
    INCLUDEPATH += $$QMAKE_INCDIR_OPENGL_ES2
    CONFIG(debug, debug|release) {
        QMAKE_LIBDIR += $$QMAKE_LIBDIR_OPENGL_ES2_DEBUG
        qtConfig(angle) {
            LIBS += $$QMAKE_LIBS_OPENGL_ES2_DEBUG
        } else {
            LIBS += $$QMAKE_LIBS_OPENGL_ES2
        }
    } else {
        LIBS += $$QMAKE_LIBS_OPENGL_ES2
        QMAKE_LIBDIR += $$QMAKE_LIBDIR_OPENGL_ES2_RELEASE
    }
    qtConfig(static): DEFINES += GL_APICALL= EGLAPI=
} else {
    !qtConfig(dynamicgl) {
        QMAKE_LIBS += $$QMAKE_LIBS_OPENGL
        QMAKE_LFLAGS += $$QMAKE_LFLAGS_OPENGL
    }
}